blob: 752cc5cadd00f9475dc9509a21efddebc8fb2d64 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
|
/* ****************************************************************************
* addin.ld -- add-in linker script.
* Copyright (C) 2017 Thomas "Cakeisalie5" Touhey <thomas@touhey.fr>
*
* This file is part of libcarrot.
* libcarrot is free software; you can redistribute it and/or modify it
* under the terms of the GNU Lesser General Public License as published by
* the Free Software Foundation; either version 3.0 of the License,
* or (at your option) any later version.
*
* libcarrot is distributed in the hope that it will be useful,
* but WITHOUT ANY WARRANTY; without even the implied warranty of
* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
* See the GNU Lesser General Public License for more details.
*
* You should have received a copy of the GNU Lesser General Public License
* along with the libcarrot; if not, see <http://www.gnu.org/licenses/>.
* ************************************************************************* */
OUTPUT_ARCH(sh3)
ENTRY(___start)
MEMORY {
rom : o = 0x00300200, l = 512k
ram : o = 0x08100000, l = 64k
}
SECTIONS {
/* ************************************************************************* */
/* ROM sections: binary code and read-only data */
/* ************************************************************************* */
.text : {
/* Initialization code. */
*(.pretext)
*(.pretext.*)
/* Constructors and destructors */
_bctors = . ; /* Begin */
*(.ctors)
_ectors = . ; /* End */
_bdtors = . ; /* Begin */
*(.dtors)
_edtors = . ; /* End */
/* Text */
*(.text)
*(.text.*)
} > rom
.rodata : {
*(.rodata)
*(.rodata.*)
_romdata = ALIGN(4) ;
} > rom
/* ************************************************************************* */
/* RAM sections: BSS and read/write data */
/* ************************************************************************* */
/* The BSS section is meant to be stripped off the ELF file to reduce binary
* size, and initialize with zeroes in the initialization routine;
* therefore its location is undefined. */
.bss : {
/* BSS */
_bbss = . ; /* Begin */
*(.bss)
_ebss = . ; /* End */
} > ram
.data : AT(_romdata) ALIGN(4) {
_bdata = . ; /* Begin */
*(.data)
*(.data.*)
_edata = . ; /* End */
} > ram
}
|